Hi Everyone,
Good day.
Has anyone tested Teltonika RUT906 with CR1000/CR800 PPP mode?
We tried serial OverIP with echo enable and partial modem control, just cannot get them connected. we used a crossed serial cable between them.
Appreciate your help.
Thanks.
TLT
Hi,
I'm using the RUT142 at two sites with CR800 and CR1000 via PPP by the loggers' serial port.
Initially, I had problems because the echo wasn't returning on the serial port from modem, so the logger wouldn't continue with the various AT commands.
Perhaps you're having the same problem.
Try using the W command in the logger menu to see what happens while the logger attempts PPP.
If so, try these AT commands via the RS232/PC or the logger's P command:
ATE1 activates the echo
AT&W saves
However, despite the OK response to saving, it doesn't seem to work, so I'm forced to send this command after every restart.
The logger turns the modem off for a minute every hour, after turn ON then sends the ATE1 command.
I remain available for further information
regards
Smile
Hi Smile,
Good day.
Thanks for your reply.
Which serial mode you used on RUT142?
I am not familiar with AT command.
Can I put the command into the Device Conguration Utility's PPP >>Modem Dial String?
Can you please share the steps of your setup.
Thanks
TLT
Repost - not sure why my post went under review.
Hi Smile,
Good day.
Thanks for your reply.
Which serial mode did you used on RUT142?
I am not familiar with AT command. Can I put the command into the Device Configuration Utility's PPP Modem Dial String?
Can you share the your setup steps.
Thanks
TLT
Hi TLT, sorryy for delay
Try with this example programm
regards
Smile
'CR1000 Series Datalogger
'Declare Public Variables
Public PTemp, Batt_volt
Public OutString(5) As String *100, InString(5) As String *100
Public set_mdm As Boolean
Public mdm_on, mdm_off
Public onPPP, offPPP
'Declare Private Variables
'Example:
'Dim Counter
'Define Data Tables.
DataTable (Test,1,-1) 'Set table size to # of records, or -1 to autoallocate.
DataInterval (0,15,Min,10)
Minimum (1,Batt_volt,FP2,False,False)
Sample (1,PTemp,FP2)
EndTable
'Main Program
BeginProg
mdm_on=58
' The modem is turned off at minute 57 of every hour to reset and reconnect to the network in case of problems, and is turned on at minute 58
mdm_off=57
onPPP=0
'In my case, PPP will be active from minute 0 to minute 20, the rest of the hour it will be possible to reach the logger via CSD calls
'In this interval I will have to carry out all the activities that require an internet connection, email, FTP, etc.
offPPP=20
set_mdm=true 'first boot configuration
SW12(1)
Delay (1,1,Min)'waiting for the modem to complete its startup procedures
Scan(1,min,1,0)
If set_mdm=true Then
'Only once after rebooting will the modem be reconfigured. It's strange, but this is what happens: after turning it off,
'the modem forgets the echo command, so at startup and every hour, the modem will be configured.
SerialOpen (comrs232,57600,0,0,10000)
OutString(1) = "ATE1"+CHR(13)'This command sets the modem to echo commands received from the logger.
SerialOut (comrs232,OutString(1),"",0,100)
SerialIn (InString(1),comrs232,100,0,1000)
OutString(2) = "AT&W0"+CHR(13)'This command sets the modem to save the config
SerialOut (comrs232,OutString(2),"",0,100)
SerialIn (InString(2),comrs232,100,0,1000)
OutString(3) = "AT+csq"+CHR(13)' This command return the signal
SerialOut (comrs232,OutString(3),"",0,100)
SerialIn (InString(3),comrs232,100,0,1000)
SerialClose (comrs232)
set_mdm= false' at the next scan these commands will not be repeated, but only at the next modem reboot
EndIf
If IfTime (mdm_on,60,min) Then
SW12(1)'the modem will be turned ON via the SW12 terminal
set_mdm=true
EndIf
If IfTime (onPPP,60,min) Then PPPOpen
'PPP will be turned off and on at the set minutes
If IfTime (offPPP,60,min) Then PPPClose
If IfTime (mdm_off,60,min) Then SW12(0)'the modem will be turned off
PanelTemp(PTemp,_50Hz)
Battery (Batt_volt)
'Enter other measurement instructions
'Call Output Tables
'Example:
CallTable Test
NextScan
EndProg
Hi Smile,
Good day.
Is ok. Thanks for your help and program.
Will try it.
Regards,
TLT